[txtadv "demo1" part 1 of 1]
[init]
title="Demo ADV I V1.11 / [C] 4/5.1995 by VT"
      "--------------------------------------------------------------------------------"
var wurfhaken=false
var stein=false
var seil=true
var schwert=true
var schlucht=false
var wurfseil=false
var wand=false
var monster=false
gtext1="Ich kenne diesen Gegenstand nicht !"
gtext2="Ich verstehe dich leider nicht. Probiere etwas Anderes !"
gtext3="Was ?" 
gtext4="Du hast diesen Gegenstand schon !"
gtext5="Das hast du schon getan !"
gtext6="Das kannst du nicht nehmen !"

[inventory]
item seil="Seil"
item schwert="Schwert"
item wurfhaken="Wurfhaken"
item stein="Stein"
(untersuche)
(betrachte)
    nl
    printdnl gtext3
  {das}Seil:
    nl
    printdnl "Schoenes, langes Seil."
  {das}Schwert:
    nl
    printdnl "Pass ja auf, dass du niemanden verletzt !"
  {den}Wurfhaken:
    nl
    if wurfhaken=false then
      printdnl gtext1
      resume
    end if
    printdnl "Das ist ein ganz gewoehnlicher Wurfhaken."
  {den}Stein:
    nl
    if stein=false then
      printdnl gtext1
      resume
    end if
    printdnl "Mittelgrosser Stein."
  otherwise:
    nl
    printdnl gtext1
(nimm)
  nl
  printdnl gtext3
  {das}seil:
    nl
    if seil=true then
      printdnl gtext4
      resume
    end if
    printdnl gtext1
  {den}wurfhaken:
    nl
    if wurfhaken=true then
      printdnl gtext4
      resume
    end if
    printdnl gtext1
  {das}schwert:
    nl
    if schwert=true then
      printdnl gtext4
      resume
    end if
    printdnl gtext1
  {den}stein:
    nl
    if stein=true then
      printdnl gtext4
      resume
    end if
    printdnl gtext1
  otherwise: 
    nl
    printdnl gtext1
(wirf)
  nl
  printdnl gtext3
  otherwise:
    nl
    printdnl gtext1
(gehe)
  nl
  printdnl "Wohin ?"
  otherwise:
    nl
    printdnl "Ich kenne diesen Ort nicht !"
(benutze)
  nl
  printdnl gtext3
  {das}seil mit {dem}wurfhaken:
  {den}wurfhaken mit {dem}seil:
    nl
    if seil=false then
      printdnl gtext1
      resume
      end if
    if wurfseil=true then
      printdnl gtext5
      resume
    end if
    printdnl "Sehr gut !"
    wurfseil=true
  otherwise:
    nl
    printdnl gtext1
(hilfe)
  text1="Dies ist ein Textadventure, d.h. du musst deine Ideen per Tastatur ein-"
        "geben ! Einige von den besseren Einfaellen erkennt dieses ADV und reagiert"
        "anschliessend darauf."
        "Hier die Befehle: Untersuche, Nimm, Benutze ... mit ..., Wirf, Toete,"
        "Rede mit ..., Gehe ([nach|in|ueber] ...)|weiter|zurueck, Schau, Inv"
        "Viel Spass wuenscht dir VT !"
  nl
  printdnl text1
  otherwise:
    nl
    printdnl gtext2
(schau)
  nl
  printdnl rinfo
  otherwise:
    nl
    printdnl gtext2
(inv)
(inventory)
(inventar)
(i)
  nl
  printdnl inventory
  otherwise:
    nl
    printdnl gtext2
(otherwise)
  nl
  printdnl gtext2

[room1]
text1="Willkommen !!!"
      ""
      "Du hast gerade das erste Demoadventure gestartet, das es im neuen TXTADV-"
      "System gibt. Leider hat diese Version wahrscheinlich noch einige Bugs."
      "Wenn dir der Computer ploetzlich abstuertzt, oder wenn irgendein Error-Code" 
      "angezeigt wird, kann dieses Programm daran schuld sein."
      "Copyright: Viktor-Technology <viktor@via.at>"
      ""
      "Taste !"
wait text1
cls
text1="Informationen ueber dieses DEMO ADV:"
      ""
      "Dieses Demo ADV soll nur demonstrieren wie dieses System arbeitet. Es wird"
      "wenig Wert auf Unterhaltung gelegt !"
      ""
      "Idee: Richard Wagner"
      "Texte: Viktor Krammer"
      "Prg: Viktor Krammer"
      ""
      "Mit 'HILFE' erhaellst du alle Befehle, die du im Spiel verwenden kannst."
      ""
      "Viel Spass wuenscht dir Viktor ..."
wait text1
cls
text1="Du stehst vor einer gefaerhlich aussehenden Hoehle. Eine Sage erzaehlt, dass"
      "in dieser Hoehle ein alter Mann lebt, der deine Wuensche erfuellen kann."
      "Doch bisher ist niemand lebend wieder aus dieser Hoehle rausgekommen."
      "Wirst du sterben, oder alle deine Wuensche erfuellt bekommen ?"
      "Dein Schicksal liegt also in dieser Hoehle."
      ""
      "Deine Ausruestung: Seil, Schwert"
      ""
      "Viel Glueck !!!"
printdnl text1
go[room2]

[room2]
rinfo="Du stehst vor einer Hoehle."
input
(untersuche)
(betrachte)
  {die}Hoehle:
    nl
    printdnl "Sieht sehr gefaehrlich aus. Noch kannst du mit QUIT aussteigen !"
  {den}Hoehleneingang:
    nl
    if wurfhaken=true then
      printdnl "In der Hoehle ist es sehr dunkel."
      resume
    end if
    printdnl "Vor dem Hoehleneingang liegt ein Wurfhaken."
  {die}Gegend:
  {die}Landschaft:
  {die}Umgebung:
    nl
    printdnl "Du stehst vor einer Hoehle. Ringsum stehen viele Baeume."
  {die}Baeume:
  {den}Baum:
    nl
    printdnl "Unheimlich."
(nimm)
  {den}Wurfhaken:
    nl
    if wurfhaken=true then
      printdnl gtext4
      resume
    end if
    printdnl "Okay."
    wurfhaken=true
  {die}Hoehle:
    nl
    printdnl "Die Hoehle ist zu gross !"
  {die}Baeume:
  {den}Baum:
    nl
    printdnl "Baeume kann ich leider nicht mitnehmen !"
(gehe{in}{die}hoehle)
  go[room3]
  otherwise:
  nl
  printdnl gtext2
(betrete)
  nl
  printdnl gtext3
  {die}hoehle:
    go [room3]
  otherwise:
    nl
    printdnl gtext2

[room3]
rinfo="Du bist in der Hoehle. Eine Schlucht versperrt Dir den Weg."
text1="Du du bist in der Hoehle. Es ist furchtbar dunkel. Fast waerst du in die"
      "Schlucht gefallen, die dir den Weg versperrt !"
cls
printdnl text1
input
(untersuche)
(betrachte)
  {die}schlucht:
    nl
    printnl "Unten siehst du einige Skelette liegen. Ansonsten ist die Schlucht mehr tief"
    printdnl "als breit."    
  {die}skelette:
    nl
    printdnl "Ich moechte nicht so sterben ! Ich hoffe du auch nicht."
(gehe)
  weiter:
  ueber {die} schlucht:
  nl
  if schlucht=false then
    printdnl "Vorsicht ! Die Schlucht ist leider zu breit, um rueberzukommen."
    resume
  end if
  go[room4]
  raus:
  zurueck:
    cls
    printdnl "Nun bist du wieder draussen."
    go [room2]
(verlasse{die}hoehle)
    cls
    printdnl "Nun bist du wieder draussen."
    go [room2]
    otherwise:
    nl
    printdnl gtext2
(benutze)
  {das}seil mit {der}schlucht:
  {die}schlucht mit {dem}seil:
    nl
    if schlucht=true then
      printdnl gtext5
      resume
    end if
    if wurfseil=false then
      printdnl "Das Seil findet einfach keinen Halt !"
      resume
    end if
    printnl "Das Seil ist auf der anderen Seite verankert. Nun kannst du auf die andere"
    printdnl "Seite gelangen !"
    schlucht=true
    seil=false
    wurfhaken=false
(wirf)
  {das}seil:  
    nl
    if schlucht=true then
      printdnl gtext5
      resume
    end if
    if wurfseil=false then
      printdnl "Das Seil findet einfach keinen Halt !"
      resume
    end if
    printnl "Das Seil ist auf der anderen Seite verankert. Nun kannst du auf die andere"
    printdnl "Seite gelangen !"
    schlucht=true
    seil=false
    wurfhaken=false
(nimm)
  {das}seil:
    nl
    if seil=true then
      printdnl gtext4
      resume
    end if
    if schlucht=true then
      printdnl "Ich brauche das Seil, um ueber die Schlucht zu kommen."
      resume
    end if
    printdnl gtext1
  {den}wurfhaken:
    nl
    if wurfhaken=true then
      printdnl gtext4
      resume
    end if
    if schlucht=true then
      printdnl "Ich brauche den Wurfhaken, um ueber die Schlucht zu kommen."
      resume
    end if
    printdnl gtext1

[room4]
rinfo="Du bist weit im inneren der Hoehle."
text1="Du bist nun weit im inneren der Hoehle. Links ist eine Wand, rechts kannst du"
      "weitergehen."
text2="Du bist nun weit im inneren der Hoehle. Du kannst nach rechts oder links"
      "weitergehen."
cls
if wand=false then
  printdnl text1
end if
if wand=true then
  printdnl text2
end if
input
(untersuche)
(betrachte)
  {die}Wand:
    nl
    if wand=false then
      printdnl "In der Wand befindet sich ein Loch."
      resume
      end if
    printdnl "Die Wand ist ein wenig verschoben."
  {das}Loch:  
    nl
    if wand=false then
      printdnl "Das Loch ist mittelgross."
      resume
      end if
    printdnl "Der Stein passt genau ins Loch."
(benutze)
  {den}stein mit {dem}Loch:
  {das}Loch mit {dem}Stein:
    nl
    if wand=true then
      printdnl gtext5
      resume
      end if
    if stein=false then
      printdnl gtext1
      resume
      end if
    printnl "Als du den Stein in das Loch gesteckt hast, bewegte sich die Wand ein wenig"
    printnl "zur Seite. Dahinter befindet sich ein anderer Raum, den du jedoch von hier"
    printdnl "nicht sehen kannst."
    stein=false
    wand=true
  {den}stein mit {der}Wand:
  {die}Wand mit {dem}Stein:
    nl
    if stein=false then
      printdnl gtext1
      resume
      end if
    printdnl "Der Stein hilft dir so nicht weiter."
(verschiebe)
  nl
  printdnl gtext3
  {die}wand:
    nl
    if wand=true then
      printdnl "Die Wand ist schon verschoben !"
      resume
      end if
    printdnl "Die Wand laesst sich nicht verschieben !"
(gehe)
  {nach} rechts:
    go [room5]
  {nach} links:
    if wand=false then
      nl
      printdnl "Du kannst nicht durch Waende gehen !"
      resume
      end if
    go [room6]
  zurueck:
    go [room3]

[room5]
rinfo="Hier liegen viele Steine herum."
text1="Hier liegen viele Steine herum. Du kannst nur wieder zurueckgehen."
cls
printdnl text1
input
(gehe)
  zurueck:
  {nach} links:
    go [room4]
(untersuche)
(betrachte)
  {den}stein:
  {die}steine:
    nl
    printdnl "Hier liegen verdammt viele Steine herum."
(nimm)
  {den}Stein:
  {einen}Stein:
    nl
    if stein=true then
      printdnl gtext4
      resume
      end if
    printdnl "Du hast einen Stein genommen."
    stein=true
  {die}steine:
    nl
    printdnl "Was willst du mit all diesen Steinen anfangen ?"

[room6]
cls
if monster=false then
  text1="Du gehst durch die Oeffnung der Wand. Dahinter greift dich ploetzlich ein"
        "boeses Monster an. Toete es bevor es dich toetet !"
  printdnl text1
  rinfo="Hilfe ! Ein Monster greift dich an."
  end if
if monster=true then
  rinfo="Ein alter Mann ist ploetzlich aufgetaucht."
  printdnl rinfo
  end if
input
(untersuche)
(betrachte)
  {das}Monster:
    nl
    if monster=false then
      printdnl "Ich hasse es ! Ausserdem greift es dich gerade an."
      resume
      end if
    printdnl "Du hast das Monster umgebracht !"
  {den}{alten}Mann:
    nl
    if monster=false then
      printdnl "Wo kann er nur sein ?"
      resume
      end if
    printdnl "Der Mann ist sehr, sehr alt."
(nimm)
  {das}monster:
    nl
    if monster=false then
      printdnl "Das Monster waehrt sich !"
      resume
      end if
    printdnl "Das ist nur ein Demo-ADV, d.h. du wirst nie ein totes Monster brauchen."
  {den}{alten}Mann:  
    nl
    if monster=false then
      printdnl gtext6
      resume
      end if
    printdnl "'Greif mich nicht an !'"
(rede mit {dem}{alten}Mann)
(sprich mit {dem}{alten}Mann)
  if monster=false then
    nl
    printdnl "Wo kann er nur sein ?"
    resume
    end if
  cls
  text1="'Aaaahhhhhh... Du hast mich also gefunden. Bis jetzt hat es noch niemand ges-"
        "schafft. Es stimmt zwar, dass ich alle Wuensche erfuellen kann, aber leider" 
        "nur meine eigenen.'"
        "Ganz umsonst war deine Muehe aber schliesslich auch nicht, denn nun hast du"
        "das erste Demo-ADV geschafft. Wenn du weniger als 1 Minute fuer das ADV ge-"
        "braucht hast, bist du sehr intelligent, bei 2-10 Minuten liegst du im Durch-"
        "schnitt und wenn du ueber eine Stunde vor dem Computer gesessen bist, ..."
        "(warst du nicht besonders ueberzeugend)"
        ""
        "'Bis bald !'"
  wait text1
  quit
(gehe)
  {nach}rechts:
  zurueck:
    nl
    if monster=false then
      printdnl "Das Monster versperrt dir den Weg."
      resume
      end if
    go [room4]
(toete)
  nl
  printdnl gtext3
  {das}Monster:
    nl
    if monster=true then
      printdnl gtext5
      resume
      end if
    printdnl "Womit denn ?"
  dich{selbst}:
    nl
    printdnl "Zuerst musst du aber noch dieses ADV zu Ende spielen."
    resume
  {das}monster mit {dem}schwert:
    nl
    if monster=true then
      printdnl gtext5
      resume
      end if
    printnl "Nach einem langen Kampf hast du das Monster getoetet."
    printdnl "Du siehst in einer Ecke eine alten Mann aufwachen."
    rinfo="Ein alter Mann schaut dich fragend an."
    monster=true
  otherwise:
    nl
    printdnl "Das kannst du nicht toeten."
(benutze)
  {das}schwert mit {dem}monster:
  {das}monster mit {dem}schwert:
    nl
    if monster=true then
      printdnl gtext5
      resume
      end if
    printnl "Nach einem langen Kampf hast du das Monster getoetet."
    printdnl "Du siehst in einer Ecke eine alten Mann aufwachen."
    rinfo="Ein alter Mann schaut dich fragend an."
    monster=true
